	ORG $2E0E
	ASC %GLOBE*****%
	ASC %MARCO-----%
	ASC %GOLDY+++++%


	ORG $A000

* FULL *

TFNT	EQU $2000
BASE	EQU $2000
GFNT	EQU $2800
WORK	EQU $2A00
BCK8	EQU $2B00
ANIM	EQU $2C00
WVRM	EQU $7000


LO	EQU $BA00
HI	EQU $BB00

OF	EQU $10

VRAM	EQU $BC00
LVRM	EQU $8000

* ZERO *

M	EQU $1

UA	EQU $80
UX	EQU $81
UY	EQU $82
HLP	EQU $83
CNT	EQU $84
POC	EQU $85
POM	EQU $86
DUX	EQU $87
HLP1	EQU $88
UB	EQU $89
UC	EQU $8A
BK	EQU $8B,$8C
MSR	EQU $8D,$8E
MSW	EQU $8F,$90
ONE	EQU $91
TEN	EQU $92

* VAR. *

NPLR	EQU $2E00
NSTN	EQU $2E01
NITT	EQU $2E02
NBCK	EQU $2E03
NROT	EQU $2E04
NBAT	EQU $2E05
NBOM	EQU $2E06
NFIR	EQU $2E09
NSND	EQU $2E0C
CFLG	EQU $2E0D
NAME	EQU $2E0E
WIN	EQU $2E2C
KOL	EQU $2E2F
POZ	EQU $2E30
DIE	EQU $2E31
DROP	EQU $2E34
FBLA	EQU $2E37
FIRE	EQU $2E3A
SPE	EQU $2E3D
VLST	EQU $2E40
LONG	EQU $2E43
BOMB	EQU $2E46
DBO	EQU $2E49
XB	EQU $2E4C
YB	EQU $2E4F
XI	EQU $2E52
YI	EQU $2E55
XS	EQU $2E58
YS	EQU $2E5E
SMER	EQU $2E61
PSM	EQU $2E64
ACNT	EQU $2E67
MOVE	EQU $2E6A
PUSH	EQU $2E6D
SPC	EQU $2E70
SPLC	EQU $2E73
SPHC	EQU $2E76
DRLC	EQU $2E79
DRHC	EQU $2E7C
FBLC	EQU $2E7F
FBHC	EQU $2E82
FILC	EQU $2E85
FIHC	EQU $2E88
MEM	EQU $2E8B
BCNT	EQU $2E8E
WHO	EQU $2EAC
BL	EQU $2ECA
BH	EQU $2EE8
WA	EQU $2F06
BIG	EQU $2F24
OX	EQU $2F42
OY	EQU $2F60
TWA	EQU $2F7E
TBIG	EQU $2F7F
TFI	EQU $2F80
TOX	EQU $2F81
TOY	EQU $2F82
YY	EQU $2F83
RES	EQU $2F84
WAY	EQU $2F85
VYS	EQU $2F86
FAZA	EQU $2F87
PAFI	EQU $2F88
ANCN	EQU $2F89
BA	EQU $2F8A
DCNT	EQU $2F8B
STAB	EQU $2F8C
PT	EQU $2F8D
END	EQU $2F8E
LCNT	EQU $2F8F
FLC	EQU $2F90
PDCN	EQU $2F91
THEEND	EQU $2F94
DLCN	EQU $2F95
ZOK	EQU $2F96

	JSR MAINSCR
	JSR INIT
AGAIN	JSR REFR
	JSR RESU
	LDA THEEND
	BEQ BN	
	LDA ZOK
	BEQ BN
	RTS	
BN	JMP AGAIN		

MAINSCR	LDA #2
	STA NBAT
	LDA #3
	STA NFIR
	LDA #1
	STA NSTN
	LDA #1
	STA NITT
	LDA #1
	STA NROT
	LDA #1
	STA NBOM
	LDA #1
	STA NPLR
	LDA #7
	STA NBCK
	LDA #0
	STA NSND
	LDA #0
	STA CFLG
	RTS

REFR	JSR ADDR
	JSR MKDL
	JSR MKRM
	JSR MKVR
	JSR MKSP
	JSR MKCT
	RTS

INIT	JSR MKSND
	JSR MKST
	RTS


MKST	LDA #0
	STA THEEND
	STA WIN
	STA WIN+1
	STA WIN+2
	LDA NBCK
	STA POZ
	LDA #0
	STA KOL
	LDA #255
	STA 764
	LDA #1
	STA 729
	STA 730
	RTS

ADDR	LDA #BASE-OF+$421:L
	STA MR10+1
	STA MR00+1
	LDA #BASE-OF+$421:H
	STA MR10+2
	STA MR00+2	
	LDA #BASE-OF+$521:L
	STA MR01+1
	LDA #BASE-OF+$521:H
	STA MR01+2
	RTS

MKDL	LDA #0
	STA 559
	LDA #DL0:L
	STA 560
	LDA #DL0:H
	STA 561
	LDA #DLI0:L
	STA 512
	LDA #DLI0:H
	STA 513
	LDA #13+16*1
	STA 708
	LDA #9+16*1
	STA 709
	LDA #5+16*1
	STA 710
	LDA #5+16*3
	STA 711
	LDA #0
	STA 712
	LDA #GFNT:H
	STA 756
	RTS	

MKRM	JSR COPY
	JSR STNS
	JSR PANT
	RTS

COPY	LDX POZ
	LDY NTB,X
	STY UY
	LDA #0
	STA POC
	LDA #29
	STA CNT	
BB	LDY UY
	LDA BCK8,Y
	STA HLP
	LDX #7
CC	LDY POC
	LDA HLP
	AND BTB,X
	BEQ AA
	LDA #1
AA	STA WORK,Y
	INC POC
	DEX
	BPL CC
	INC UY
	DEC CNT
	BPL BB
	LDY POC
	LDA #255
	STA WORK,Y
	RTS

NTB	DFB 0,30,60,90,120
	DFB 150,180,210
BTB	DFB 1,2,4,8,16,32,64,128

STNS	LDA NSTN
	BEQ DD
	LDX #0
FF	LDA WORK,X
	BNE EE
	LDA NSTN
	CMP #1
	BEQ GG
	LDA #2
	JMP HH
GG	LDA 53770
	AND #2
HH	STA WORK,X
EE	INX
	BNE FF
DD	LDA #0
	STA WORK
	STA WORK+1
	STA WORK+20
	STA WORK+18
	STA WORK+19
	STA WORK+39
	STA WORK+200
	STA WORK+220
	STA WORK+221
	STA WORK+219
	STA WORK+238
	STA WORK+239
	RTS

PANT	LDX #0
	LDA #VRAM:L
	STA BK
	LDA #VRAM:H
	STA BK+1
LL	LDA #19
	STA CNT
II	LDA WORK,X
	CMP #255
	BNE KK
	RTS
KK	JSR BLOK
	INX
	LDA BK
	CLC
	ADC #2
	STA BK
	BCC JJ
	INC BK+1
JJ	DEC CNT
	BPL II
	LDA BK
	CLC
	ADC #40
	STA BK
	BCC MM
	INC BK+1
MM	JMP LL

BLOK	ASL
	ASL
	LDY #0
	STA (BK),Y
	CLC
	ADC #1
	LDY #40
	STA (BK),Y
	CLC
	ADC #1
	LDY #1
	STA (BK),Y
	CLC
	ADC #1
	LDY #41
	STA (BK),Y
	RTS

BLO1	ASL
	ASL
	ORA #128
	LDY #0
	STA (BK),Y
	CLC
	ADC #1
	LDY #40
	STA (BK),Y
	CLC
	ADC #1
	LDY #1
	STA (BK),Y
	CLC
	ADC #1
	LDY #41
	STA (BK),Y
	RTS

MKVR	LDA #255
	STA DCNT
	LDA #0
	STA FLC
	STA LCNT
	STA ZOK
	LDX #2
RR	JSR SET
	LDA NBOM
	STA BOMB,X
	LDA NFIR
	STA LONG,X
	LDA #0
	STA DBO,X
	STA DIE,X
	STA SMER,X
	STA PUSH,X
	STA ACNT,X
	LDA #1
	STA PSM,X
	STA SPC,X
	STA MOVE,X
	LDA #63
	STA PDCN,X
	DEX
	BPL RR
	LDX #29
	LDA #255
RR1	STA BCNT,X
	DEX
	BPL RR1
	RTS	

MKCT	LDA #0
	STA END
	LDA #7
	LDX #VBI0:H
	LDY #VBI0:L
	JSR $E45C
	LDA #192
	STA 54286
	LDA #58
	STA 559
	LDA #10
	STA M
	LDA NSND
	BNE PP
	JSR SND0
	RTS
PP	JSR SND1
	RTS

SND1	LDA 20
NN	CMP 20
	BEQ NN
	JSR CMC
	JMP SND1

DL0	DFB 112,0,68
	DFW VRAM
	DFB 4,4,4,4,4,4,4,4,4,4,4,4
	DFB 4,4,4,4,4,4,4,4,4,4,132
	DFB 0,78
	DFW LVRM
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,142,0

	DFB 0,66,L0:L,L0:H
	DFB 65,DL0:L,DL0:H

L0	ASC % $ This game was don%
	ASC %e by GMG in 1997. $ %

DLI0	PHA
	LDA #13+16*0
	STA $D40A
	STA 53270
	LDA #9+16*0
	STA 53271
	LDA #5+16*0
	STA 53272
	LDA #DLI01:L
	STA 512
	LDA #DLI01:H
	STA 513
	PLA
	RTI

DLI01	PHA
	LDA #0
	STA $D40A
	STA 53272
	LDA #TFNT:H
	STA 54281
	PLA
	RTI

MKSP	JSR INI
	LDA NPLR
	BEQ TW0
	JSR TH0
	RTS
TW0	JSR TW1	
	RTS

TW1	LDA #33
	STA 623
	LDY #0
	STY YS
	STY XI
	STY XI+1
	STY YI
	STY YI+1
	STY XB
	STY YB
	LDY #176
	STY YS+1
	LDA #47
	STA XS
	LDA #199
	STA XS+1
	LDA #19
	STA XB+1
	LDA #11
	STA YB+1
	LDA #168
	STA 704
	LDA #164
	STA 705
	LDA #20
	STA 706
	LDA #18
	STA 707
	JSR PA2
	RTS

PA2	LDA #1
	STA CNT
	INC MR00+2
	INC MR00+2
	INC MR01+2
	INC MR01+2

A8	LDX CNT
	BNE A9
	DEC MR00+2
	DEC MR00+2
	DEC MR01+2
	DEC MR01+2
	LDA XS
	STA 53248
	STA 53249
	JMP A91
A9	LDA XS+1
	STA 53250		
	STA 53251
A91	LDA MOVE,X
	BEQ A3
	LDA SMER,X
	STA POM
	CMP PSM,X
	BNE A4
	INC ACNT,X
	LDA ACNT,X
	CMP #3
	BNE A5
A4	LDA #0
	STA ACNT,X
A5	STA HLP
	LDY YS,X
	TYA
	STA MEM,X
	LDX POM
	LDA QTB,X
	TAX
 	JSR A7
	STY UY
	LDY HLP
	TXA
	CLC
	ADC ITB,Y
	TAX
	LDY UY
	JSR A7
A3	DEC CNT
	BPL A8
	LDY MEM
	LDA #0
	STA BASE-OF+$41F,Y
	STA BASE-OF+$420,Y
	STA BASE-OF+$42E,Y
	STA BASE-OF+$42D,Y
	STA BASE-OF+$51F,Y
	STA BASE-OF+$520,Y
	STA BASE-OF+$52E,Y
	STA BASE-OF+$52D,Y
	LDY MEM+1
	STA BASE-OF+$61F,Y
	STA BASE-OF+$620,Y
	STA BASE-OF+$62E,Y
	STA BASE-OF+$62D,Y
	STA BASE-OF+$71F,Y
	STA BASE-OF+$720,Y
	STA BASE-OF+$72E,Y
	STA BASE-OF+$72D,Y
	RTS

A7	LDA #5
	STA POC
A2	LDA ANIM,X
MR00	STA BASE-OF+$421,Y
	LDA ANIM+6,X
MR01	STA BASE-OF+$521,Y
	INX
	INY
	DEC POC
	BPL A2
	RTS

QTB	DFB 0,48,96,144
ITB	DFB 6,18,30
Q1TB	DFB 0,24,48,72
I1TB	DFB 0,6,12

INI	LDX #0
	TXA
A1	STA BASE+1024,X
	STA BASE+1280,X
	STA BASE+1536,X
	STA BASE+1792,X
	INX
	BNE A1
	LDA #0
	STA 53256
	STA 53257
	STA 53258
	STA 53259
	LDA #2
	STA 53277
	STA 53278
	LDA #BASE:H
	STA 54279
	RTS

TH0	LDA #1
	STA 623
	LDY #0
	STY YS
	STY XI
	STY XI+1
	STY XI+2
	STY YI
	STY YI+1
	STY YI+2
	STY XB
	STY YB
	STY YB+1
	STY YS+1
	LDY #176
	STY YS+2
	LDA #47
	STA XS
	LDA #199
	STA XS+1
	STA XS+2
	LDA #19
	STA XB+1
	STA XB+2
	LDA #11
	STA YB+2
	LDA #13
	STA 704
	LDA #42
	STA 705
	LDA #100
	STA 706
	JSR PA3	
	RTS

PA3	LDA #2
	STA CNT
	INC MR10+2
	INC MR10+2
	INC MR10+2

B2	LDX CNT
	LDA XS,X
	STA 53248,X
	DEC MR10+2
	LDA MOVE,X
	BEQ B4
	LDA SMER,X
	STA POM
	CMP PSM,X
	BNE B6
	INC ACNT,X
	LDA ACNT,X
	CMP #3
	BNE B5
B6	LDA #0
	STA ACNT,X
B5	STA HLP
	LDY YS,X
	TYA
	STA MEM,X
	LDX POM
	LDA Q1TB,X
	TAX
 	JSR B0
	STY UY
	LDY HLP
	TXA
	CLC
	ADC I1TB,Y
	TAX
	LDY UY
	JSR B0
B4	DEC CNT
	BPL B2
	LDY MEM
	LDA #0
	STA BASE-OF+$41F,Y
	STA BASE-OF+$420,Y
	STA BASE-OF+$42E,Y
	STA BASE-OF+$42D,Y
	LDY MEM+1
	STA BASE-OF+$51F,Y
	STA BASE-OF+$520,Y
	STA BASE-OF+$52E,Y
	STA BASE-OF+$52D,Y
	LDY MEM+2
	STA BASE-OF+$61F,Y
	STA BASE-OF+$620,Y
	STA BASE-OF+$62E,Y
	STA BASE-OF+$62D,Y
	RTS

B0	LDA #5
	STA POC
B1	LDA ANIM+192,X
MR10	STA BASE-OF+$421,Y
	INX
	INY
	DEC POC
	BPL B1
	RTS

VBI0	JSR SDLI
	LDA END
	CMP #3
	BEQ RSL
	CMP #2
	BEQ DEN
	JSR IN
	JSR SMRT
	JSR CTRL
	JSR ANMC
	JSR TIME
	LDA END
	CMP #1
	BEQ X1
	JSR POLO
X1	JSR BLOW
	JSR BANM
	JSR DANM
	JSR OUTG
	JMP DEN
RSL	JSR HOLD
DEN	JMP $E462

OUTG	STA 53278

	LDA NPLR
	BEQ TD2

	LDA PDCN
	BNE W4
	STA 53248
W4	LDA PDCN+1
	BNE W5
	STA 53249
W5	LDA PDCN+2
	BNE W6
	STA 53250	
W6	RTS

TD2	LDA PDCN
	BNE W0
	STA 53248
	STA 53249
W0	LDA PDCN+1
	BNE W1
	STA 53250
	STA 53251
W1	RTS

SDLI	LDA #DLI0:L
	STA 512
	LDA #DLI0:H
	STA 513
	LDA #0
	STA 77
	RTS

IN	LDA #0
	STA 77
	STA PAFI
	LDX #2
B9	LDA #0
	STA MOVE,X
	STA PUSH,X	
	LDA SMER,X
	STA PSM,X
	DEX
	BPL B9
	RTS

CTRL	LDA NPLR
	BNE TH1
	JSR FTWO
	RTS
TH1	JSR FTWO
	LDA CFLG
	BEQ XE
	JSR CXL
	RTS
XE	JSR CXE
	RTS

C41	JMP C4
FTWO	LDX #1
C5	LDA DIE,X
	BNE C41
	DEC SPC,X
	BPL C4
	LDA SPE,X
	STA SPC,X	

	LDA 632,X
	CMP #15
	BEQ C0
	STA HLP1
	LDA #1
	STA MOVE,X
	LDA HLP1
	AND #2
	BNE C1
	LDA #0
	STA SMER,X
	STX DUX
	JSR LOOK
	LDX DUX
C1	LDA HLP1
	AND #1
	BNE C2
	LDA #1
	STA SMER,X
	STX DUX
	JSR LOOK
	LDX DUX
C2	LDA HLP1
	AND #8
	BNE C3
	LDA #3
	STA SMER,X
	STX DUX
	JSR LOOK
	LDX DUX
C3	LDA HLP1
	AND #4
	BNE C0
	LDA #2	
	STA SMER,X
	STX DUX
	JSR LOOK
	LDX DUX
C0	LDA DROP,X
	BEQ C4
	CMP #2
	BEQ C6
	LDA 644,X
	BNE C4
C6	LDA #1
	STA PUSH,X
C4	DEX
	BPL C51
	RTS

C51	JMP C5

D01	JMP D0
CXE	LDA DIE+2
	BNE D01
	DEC SPC+2
	BPL D01
	LDA SPE+2
	STA SPC+2
	LDA 764
	CMP #255
	BEQ D2
	AND #191
	STA HLP1
	LDA #255
	STA 764
	LDA HLP1
	CMP #$2F
	BNE D1
	LDA #1
	STA SMER+2	
	STA MOVE+2
	LDX #2
	JSR LOOK
D1	LDA HLP1
	CMP #$3F
	BNE D2
	LDA #0
	STA SMER+2
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK
D2	LDA 53279
	STA HLP1
	CMP #7
	BEQ D4
	CMP #6
	BNE D3
	LDA #2
	STA SMER+2
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK
D3	LDA HLP1
	CMP #5
	BNE D4
	LDA #3
	STA SMER+2
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK
D4	LDA $D20F
	AND #8
	BNE D0
	LDA #1
	STA PUSH+2
D0	RTS

E01	JMP E0

CXL	LDA DIE+2
	BNE E01
	DEC SPC+2
	BPL E01
	LDA SPE+2
	STA SPC+2
	LDA 53279
	STA HLP1
	CMP #7
	BEQ E1
	CMP #6
	BNE E2
	LDA #1
	STA SMER+2
	STA MOVE+2
	LDX #2
	JSR LOOK
E2	LDA HLP1
	CMP #5
	BNE E1
	LDA #0
	STA SMER+2
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK
E1	LDA 764
	CMP #255
	BEQ E3
	AND #191
	STA HLP1
	LDA #255
	STA 764
	LDA HLP1
	CMP #$3E
	BNE E3
	LDA #3
	STA SMER+2	
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK

E3	LDA HLP1
	CMP #$3F
	BNE E4
	LDA #2
	STA SMER+2
	LDA #1
	STA MOVE+2
	LDX #2
	JSR LOOK
E4	LDA $D20F
	AND #8
	BNE E0
	LDA #1
	STA PUSH+2
E0	RTS

ANMC	LDA NPLR
	BNE TH2
	JSR PA2
	RTS
TH2	JSR PA3
	RTS

LOOK	LDA MOVE,X
	BEQ F1
	LDY SMER,X
	LDA LTB,Y
	STA MR20+1
	LDA HTB,Y
	STA MR20+2
MR20	JSR DO
F1	RTS

LTB	DFB DO:L,UP:L,LE:L,RI:L
HTB	DFB DO:H,UP:H,LE:H,RI:H

SCAN	LDA #0
	STA HLP
	STA UA
	LDY YB,X
	LDA MTB,Y
	CLC
	ADC XB,X
	LDY SMER,X
	CLC
	ADC STB,Y
	STA POM
	TAY
	JSR H3
	LDA SMER,X
	AND #2
	BNE H4
	LDA XI,X
	CMP #3
	BPL H5
	RTS
H4	LDA YI,X
	CMP #6
	BPL H5
	RTS
H5	LDY SMER,X
	LDA POM
	CLC
	ADC CTB,Y	
	TAY
	LDA #1
	STA UA
	JSR H3
	RTS

H3	LDA WORK,Y
	BMI H1
	BEQ H1
	CMP #1
	BEQ H2
	CMP #2
	BEQ H2
	CMP #7
	BEQ H2
	STA CNT
	JSR TAKE
	RTS
H2	LDA #1
	STA HLP
H1	RTS

MTB	DFB 0,20,40,60,80,100,120
	DFB 140,160,180,200,220
STB	DFB 20,236,255,1
CTB	DFB 1,1,20,20
DTB	DFB 0,80,160,240,64,144
	DFB 224,48,128,208,32,112
ETB	DFB $BC,$BC,$BC,$BC,$BD,$BD
	DFB $BD,$BE,$BE,$BE,$BF,$BF

FTB	DFB 80,0,0,2
GTB	DFB 0,80,2,0

JTB	DFB 2,2,80,80


TAKE	LDA #0
	STA WORK,Y
	LDA XB,X
	ASL
	STA POC
	LDY YB,X
	LDA DTB,Y
	CLC
	ADC POC
	STA BK
	LDA ETB,Y
	ADC #0
	STA BK+1
	LDY SMER,X
	LDA BK
	CLC
	ADC FTB,Y
	STA BK
	BCC I0
	INC BK+1
I0	LDA BK
	SEC
	SBC GTB,Y
	STA BK
	BCS I1
	DEC BK+1
I1	LDA UA
	BEQ I3

	LDA BK
	CLC 
	ADC JTB,Y
	STA BK
	BCC I3
	INC BK+1

I3	LDA #0
	JSR BLOK
	LDA CNT
	CMP #3
	BEQ RND
	CMP #4
	BEQ STOP
	CMP #5
	BEQ PLB
	LDA #8
	STA M
	LDA LONG,X
	CMP #19
	BEQ I4
	INC LONG,X
I4	RTS
PLB	LDA #8
	STA M
	LDA BOMB,X
	CMP #10
	BEQ I5
	INC BOMB,X
I5	RTS

STOP	JSR SET
	RTS


RND	LDA #12
	STA M
	JSR SET
	LDA 53770
	AND #7
	BEQ I5
	CMP #1
	BEQ J1
	CMP #2
	BEQ J2
	CMP #3
	BEQ J3
	CMP #4
	BEQ J4
	CMP #5
	BEQ J5
	CMP #6
	BEQ J6
	LDA #1
	STA FBLA,X
	LDA #4
	STA VLST,X
	RTS
J1	LDA #0
	JMP J7
J2	LDA #3
J7	STA SPE,X
	LDA #1
	STA VLST,X
	RTS
J3	LDA #2
	JMP J8
J4	LDA #0
J8	STA FIRE,X
	LDA #3
	STA VLST,X
	RTS
J5	LDA #2
	JMP J9
J6	LDA #0
J9	STA DROP,X
	LDA #2
	STA VLST,X
	RTS

SET	LDA #0
	STA VLST,X
	STA SPLC,X
	STA SPHC,X
	STA DRLC,X
	STA DRHC,X
	STA FBLC,X
	STA FBHC,X
	STA FILC,X
	STA FIHC,X
	STA FBLA,X
	LDA #1
	STA DROP,X
	STA FIRE,X
	STA SPE,X
	RTS

K7	JMP K9

TIME	LDX NPLR
	CPX DCNT
	BNE K11
	LDA #1
	STA FLC
	STA END
K11	INX
K0	LDA VLST,X
	BEQ K7
	CMP #1
	BEQ K1
	CMP #2
	BEQ K2
	CMP #3
	BEQ K3
	INC FBLC,X
	BNE K9
	INC FBHC,X
	LDA FBHC,X
	CMP #6
	BNE K9
	LDA #0
	STA VLST,X
	STA FBLA,X
	STA FBLC,X
	STA FBHC,X
	JMP K9	
K1	INC SPLC,X
	BNE K9
	INC SPHC,X
	LDA SPHC,X
	CMP #6
	BNE K9
	LDA #0
	STA VLST,X
	STA SPLC,X
	STA SPHC,X
	LDA #1
	STA SPE,X
	JMP K9	
K2	INC DRLC,X
	BNE K9
	INC DRHC,X
	LDA DRHC,X
	CMP #6
	BNE K9
	LDA #0
	STA VLST,X
	STA DRLC,X
	STA DRHC,X
	LDA #1
	STA DROP,X
	JMP K9	
K3	INC FILC,X
	BNE K9
	INC FIHC,X
	LDA FIHC,X
	CMP #6
	BNE K9
	LDA #0
	STA VLST,X
	STA FILC,X
	STA FIHC,X
	LDA #1
	STA FIRE,X
K9	DEX
	BPL K8
	LDA FLC
	BEQ K12
	DEC LCNT
	BNE K12
	LDA #2
	STA END
K12	RTS

K8	JMP K0

RI	LDA XS,X
	CMP #201
	BEQ G0
	LDA XI,X
	CMP #2
	BNE G1
	JSR SCAN
	LDA HLP
	BNE G0
G1	INC XS,X
	INC XI,X
	LDA XI,X
	CMP #8
	BNE G0
	LDA #0
	STA XI,X
	INC XB,X
G0	RTS

LE	LDA XS,X
	CMP #47
	BEQ G2
	LDA XI,X
	BNE G3
	JSR SCAN
	LDA HLP
	BNE G2
G3	DEC XS,X
	DEC XI,X
	LDA XI,X
	BPL G2
	LDA #7
	STA XI,X
	DEC XB,X
G2	RTS

DO	LDA YS,X
	CMP #180
	BEQ G4
	LDA YI,X
	CMP #4
	BNE G5
	JSR SCAN
	LDA HLP
	BNE G4
G5	INC YS,X
	INC YS,X
	INC YI,X
	INC YI,X
	LDA YI,X
	CMP #16
	BNE G4
	LDA #0
	STA YI,X
	INC YB,X
G4	RTS


UP	LDA YS,X
	BEQ G6
	LDA YI,X
	BNE G7
	JSR SCAN
	LDA HLP
	BNE G6
G7	DEC YS,X
	DEC YS,X
	DEC YI,X
	DEC YI,X
	LDA YI,X
	BPL G6
	LDA #14
	STA YI,X
	DEC YB,X
G6	RTS

POLO	LDX NPLR
	INX 
M0	STX UX
	LDA DBO,X
	CMP BOMB,X
	BEQ M1
	LDA PUSH,X
	BEQ M1
	JSR EXAM
	LDA HLP
	BNE M1
	LDY #29
M3	LDA BCNT,Y
	CMP #255
	BEQ M4
M2	DEY
	BPL M3
	RTS
M4	JSR PARA
M1	LDX UX
	DEX
	BPL M0
	RTS

EXAM	LDA #0
	STA HLP
	LDY YB,X
	LDA MTB,Y
	CLC
	ADC XB,X
	TAY
	LDA WORK,Y
	BEQ M5
	LDA #1
	STA HLP
M5	RTS

PARA	LDA XB,X
	STA OX,Y
	LDA YB,X
	STA OY,Y
	INC DBO,X
	TXA
	STA WHO,Y
	LDA FBLA,X
	BEQ N3
	LDA #75
	JMP N4
N3	LDA #150
N4	STA BCNT,Y
	LDA FIRE,X
	BEQ N0
	CMP #1
	BEQ N1
	LDA #19
	JMP N2
N0	LDA #3
	JMP N2
N1	LDA LONG,X
N2	STA BIG,Y
	LDA XB,X
	STA UB
	LDA YB,X
	STA UC
	TAX
	LDA MTB,X
	CLC
	ADC UB
	STA WA,Y
	TAX
	LDA #7
	STA WORK,X
	LDA UB
	ASL
	STA POC
	LDX UC
	LDA DTB,X
	CLC
	ADC POC
	STA BK
	STA BL,Y
	LDA ETB,X
	ADC #0
	STA BK+1
	STA BH,Y
	LDA #7
	JSR BLOK
	RTS

BLOW	LDY #29
O1	STY UY
	LDA BCNT,Y
	CMP #255
	BEQ O0
	TYA
	TAX	
	DEC BCNT,X
	BNE O2
	LDA PAFI
	CMP #3	
	BNE T4
	INC BCNT,X
	JMP O0
T4	JSR OUTF
	JMP O0
O2	LDA BCNT,X
	CMP #20
	BNE O3
	LDA PAFI
	CMP #3
	BNE T1
	INC BCNT,X
	JMP O3
T1	JSR PH1
	JMP O0
O3	LDA BCNT,X
	CMP #10
	BNE O4
	LDA PAFI
	CMP #3
	BNE T2
	INC BCNT,X
	JMP O4
T2	JSR PH2
	JMP O0
O4	LDA BCNT,X
	CMP #5
	BNE O0
	LDA PAFI
	CMP #3
	BNE T3
	INC BCNT,X
	JMP O0
T3	JSR PH3
O0	LDY UY
	DEY
	BPL O1
	RTS

PH2	LDA #9
	STA FAZA
	JSR IPH
	RTS

PH3	LDA #10
	STA FAZA
	JSR IPH
	RTS

IPH	INC PAFI
	STY YY
	JSR REF
	TYA
	ORA #128
	STA TFI
	LDX FAZA
	BNE S0
	LDX TWA
	LDA #0
	STA WORK,X
S0	LDA FAZA
	JSR BLO1
	LDA #0
	STA WAY
	JSR VS1
	JSR REF
	LDA #1
	STA WAY
	JSR VS1
	JSR REF
	LDA #2
	STA WAY
	JSR VS1
	JSR REF
	LDA #3
	STA WAY
	JSR VS1
	RTS

VS1	LDX TWA
S5	JSR KDE	
	LDA VYS
	BNE S1
	JSR SCN1
	LDA RES
	BNE S5
	LDA FAZA
	BNE S2
	STA WORK,X
S2	JSR BLO1
	JMP S5
S1	RTS

SCN1	LDA #0
	STA RES
	LDA WORK,X
	CMP TFI
	BEQ S3
	LDA #1
	STA RES
S3	RTS

RTB	DFB 2,4,6,2

PH1	STY YY
	LDA 53770
	AND #3
	TAY
	LDA RTB,Y
	STA M	
	INC PAFI
	JSR REF
	TYA
	ORA #128
	STA TFI
	LDX TWA
	STA WORK,X
	LDA #8
	JSR BLO1
	LDA #0
	STA WAY
	JSR VS
	JSR REF
	LDA #1
	STA WAY
	JSR VS
	JSR REF
	LDA #2
	STA WAY
	JSR VS
	JSR REF
	LDA #3
	STA WAY
	JSR VS
	RTS

REF	LDY YY
	LDA BL,Y
	STA BK
	LDA BH,Y
	STA BK+1
	LDA WA,Y
	STA TWA	
	LDA BIG,Y
	STA TBIG
	LDA OX,Y
	STA TOX
	LDA OY,Y
	STA TOY
	RTS

VS	LDX TWA
P5	JSR KDE	
	LDA VYS
	BNE P1
	JSR SCNN
	LDA RES
	BNE P1
	LDA TFI
	STA WORK,X
	LDA #8
	JSR BLO1
	JMP P5
P1	RTS

SCNN	LDA #0
	STA RES
	LDA WORK,X
	BEQ P4
	BMI P4
	CMP #1
	BEQ P3
	CMP #2
	BEQ P6
	CMP #7
	BEQ P7
P8	LDA #0
	STA WORK,X
	JSR BLO1
P3	LDA #1
	STA RES
P4	RTS

P6	LDA NITT
	BEQ P8
	CMP #2
	BEQ P9
	LDA 53770
	AND #1
	BNE P8
P9	LDA 53770
	AND #3
	CLC
	ADC #3
	STA WORK,X
	JSR BLOK
	JMP P3

P7	LDX #29
Q1	LDA OX,X
	CMP TOX
	BNE Q0
	LDA OY,X
	CMP TOY
	BNE Q0
	LDA #21
	STA BCNT,X
	JMP P3
Q0	DEX
	BPL Q1
	JMP P3

KDE	LDA #0
	STA VYS
	LDA WAY
	BEQ R0
	CMP #1
	BEQ R1
	CMP #2
	BEQ R2

	LDA TOY
	CMP #11	
	BEQ R3
	DEC TBIG
	BEQ R3
	INC TOY
	TXA
	CLC
	ADC #20
	TAX
	LDA BK
	CLC
	ADC #80
	STA BK
	BCC R4
	INC BK+1
	RTS

R0	LDA TOX
	BEQ R3
	DEC TBIG
	BEQ R3
	DEC TOX
	DEX
	LDA BK
	SEC
	SBC #2
	STA BK
	BCS R4
	DEC BK+1
R4	RTS
R3	LDA #1
	STA VYS
	RTS
R1	LDA TOX
	CMP #19
	BEQ R3
	DEC TBIG
	BEQ R3
	INC TOX
	INX
	LDA BK
	CLC
	ADC #2
	STA BK
	BCC R4
	INC BK+1
	RTS

R2	LDA TOY
	BEQ R3
	DEC TBIG
	BEQ R3
	DEC TOY
	TXA
	SEC
	SBC #20
	TAX
	LDA BK
	SEC
	SBC #80
	STA BK
	BCS R4
	DEC BK+1
	RTS

OUTF	STY UY
	LDA #0
	STA FAZA
	JSR IPH
	LDY UY
	LDA #255
	STA BCNT,Y
	LDA WHO,Y
	TAX
	DEC DBO,X
	RTS

BANM	LDA ANCN
	BEQ CK
	DEC ANCN
	RTS	
CK	LDA #30
	STA ANCN
	LDA BA
	EOR #1
	STA BA
	LDA BA
	BEQ D3W
	LDY #128+7
	JMP LL6
D3W	LDY #7
LL6	LDX #7
LL5	LDA $2960,Y
	STA $28E0,X
	LDA $2968,Y
	STA $28E8,X
	LDA $2970,Y
	STA $28F0,X
	LDA $2978,Y
	STA $28F8,X
	DEY
	DEX
	BPL LL5
	RTS

SMRT	LDA NPLR
	BNE TH3

	TAX
	INX
U2	LDA DIE,X
	BNE U05
	TXA
	ASL
	TAX
	LDA 53252,X	
	AND #8
	BNE U4
	LDA 53253,X
	AND #8
	BEQ U3
U4	TXA
	LSR
	TAX
	LDA #1
	STA DIE,X	
	INC DCNT
	LDA 53770
	AND #2
	CLC
	ADC #14
	STA M
	JMP U05	
U3	TXA
	LSR
	TAX
U05	DEX
	BPL U2
	RTS

TH3	TAX
	INX
U0	LDA DIE,X
	BNE U1
	LDA 53252,X
	AND #8
	BEQ U1
	LDA #1
	STA DIE,X	
	INC DCNT
	LDA 53770
	AND #2
	CLC
	ADC #14
	STA M
U1	DEX
	BPL U0
	RTS

DANM	LDX NPLR
	INX
V0	LDA DIE,X
	BEQ V1
	LDA PDCN,X
	BEQ V1
	DEC PDCN,X
	JSR FADE
V1	DEX
	BPL V0
	RTS

FADE	LDA NPLR
	BNE TH9
	LDA PDCN,X
	CPX #1
	BEQ PJ2
	LSR
	LSR
	STA 704
	STA 705
	RTS
PJ2	LSR
	LSR
	STA 706
	STA 707
	RTS
TH9	LDA PDCN,X
	LSR
	LSR
	STA 704,X
	RTS

MKSND	LDX #0
X	TXA
	AND #15
	ORA #16
	STA LO,X
	TXA
	LSR
	LSR
	LSR
	LSR
	ORA #16
	STA HI,X
	DEX
	BNE X
	RTS

SND0	LDA END
	CMP #2
	BNE VOR
	RTS
VOR	LDA M
	BMI LOOP
	BEQ SND0
	TAX
	LDA TAB,X
	STA MSR
	LDA TAB+1,X
	STA MSR+1
	LDA TAB+2,X
	STA MSW
	LDA TAB+3,X
	STA MSW+1
	STX PT
	LDA #$FF
	STA M

LOOP	LDA (MSR),Y
	TAX
	LDA LO,X
	STA $D201
	STA $D40A
	STA $D40A
	LDA HI,X
	STA $D201
	STA $D40A
	STA $D40A
	INC MSR
	BNE LLL
	INC MSR+1
LLL	LDA MSR+1
	CMP MSW+1
	BNE VOR
	LDA #0
	STA M
	JMP SND0

TAB	DFW 0,$3000,$3AFF,$4090,$4BFF
	DFW $5470,$6108,$68FF,$7558
	DFW $7ED0

V	NOP

CMC	RTS

RESU	JSR PREP
	JSR VYSL
	LDA THEEND
	BEQ OW2
	JSR ZAVER
OW2	RTS


PREP	LDA NROT
	BEQ OW
	INC POZ
	LDA POZ
	AND #7
	STA POZ
OW	INC KOL
	LDA KOL
	CMP NBAT
	BMI OW1
	LDA #1
	STA THEEND
OW1	RTS

VYSL	LDA #0
	STA 709
	STA 710
	STA 53248
	STA 53249
	STA 53250
	STA 53251

	STA DLCN
	LDA #DL1:L
	STA 560
	LDA #DL1:H
	STA 561
	LDA #DLI2:L
	STA 512
	LDA #DLI2:H
	STA 513
	LDA #192
	STA 54286
	LDA #TFNT:H
	STA 756
	LDA #3
	STA END
	JSR WRITE
WP	LDA 53279
	CMP #3
	BNE WP
	RTS

HOLD	LDA #0
	STA DLCN
	LDA #DLI2:L
	STA 512
	LDA #DLI2:H
	STA 513
	RTS

RTTB	DFW DLI3,DLI5,DLI2

DLI2	PHA
	TXA
	PHA
	LDX DLCN
	LDA RTTB,X
	STA 512
	LDA RTTB+1,X
	STA 513
	INX
	INX
	STX DLCN
	LDX #0
AZ1	TXA
	ORA #16*4
	STA $D40A
	STA 53274
	INX
	INX
	CPX #16
	BNE AZ1	
	LDX #14
AZ2	TXA
	ORA #16*4
	STA $D40A
	STA 53274
	DEX
	DEX
	BPL AZ2	
	LDA #0
	STA 53274
	PLA
	TAX
	PLA
	RTI

DLI3	PHA
	LDA #13+16*0
	STA $D40A
	STA 53270
	LDA #9+16*0
	STA 53271
	LDA #5+16*0
	STA 53272
	LDA #DLI4:L
	STA 512
	LDA #DLI4:H
	STA 513
	PLA
	RTI

DLI4	PHA
	LDA #13+16*2
	STA $D40A
	STA 53270
	LDA #9+16*2
	STA 53271
	LDA #5+16*2
	STA 53272
	LDA #DLI2:L
	STA 512
	LDA #DLI2:H
	STA 513
	PLA
	RTI

DLI5	PHA
	LDA #10
	STA $D40A
	STA 53271
	LDA #0
	STA 53272
	LDA #DLI2:L
	STA 512
	LDA #DLI2:H
	STA 513
	PLA
	RTI

DL1	DFB 112,112
	DFB 112,112,112,128,112,112
	DFB 128,32,78,LVRM:L,LVRM:H
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,128
	DFB 16,128,112,112,128
	DFB 32,66
	DFW LINE1
	DFB 112,66
	DFW LINE2
	DFB 112,66
	DFW LINE4
	DFB 66
	DFW LINE5
	DFB 66
	DFW LINE6
	DFB 112,66
	DFW LINE3		
	DFB 32,128
	DFB 112,112,65,DL1:L
	DFB DL1:H

LINE1	ASC %  The winner of round:%
	ASC %    is            %

LINE7	ASC %Equal scores - you m%
	ASC %ust play next round!%
LINE8	ASC %  The winer of this %
	ASC %game is:            %

LINE4	ASC %             %
	ASC %              %
	ASC %             %
LINE5	ASC %             %
	ASC %              %
	ASC %             %
LINE6	ASC %             %
	ASC %              %
	ASC %             %

LINE2	ASC %   The total results%
	ASC % of all players :   %
LINE3	ASC %Press Esc for menu o%
	ASC %r fire for continue.%



NUMB	LDY #255
ER1	INY
	SEC
	SBC #10
	BPL ER1
	CLC
	ADC #26
	STA LINE1+1,X
	TYA
	ORA #16
	STA LINE1,X
	RTS

HRC	LDA #9
	STA CNT
UL0	LDA NAME,X
	STA LINE1,Y
	INY
	INX
	DEC CNT
	BPL UL0
	RTS

NBD	LDY #9
AZ	LDA IT,Y
	STA LINE1+29,Y
	DEY
	BPL AZ
	RTS

IT	ASC %  Nobody  %

WRITE	LDA KOL
	LDX #23
	JSR NUMB
	LDA NPLR
	BEQ TW08
	LDA DIE
	BNE XA0
	INC WIN
	LDX #0
	LDY #29
	JSR HRC
	JMP XA2
XA0	LDA DIE+1
	BNE XA1
	INC WIN+1
	LDX #10
	LDY #29
	JSR HRC
	JMP XA2
XA1	LDA DIE+2
	BNE XA3
	INC WIN+2
	LDX #20
	LDY #29
	JSR HRC
	JMP XA2
XA3	JSR NBD
XA2	JSR REBR
	RTS

TW08	LDA DIE
	BNE GH0
	INC WIN
	LDX #0
	LDY #29	
	JSR HRC
	JMP GH2
GH0	LDA DIE+1
	BNE GH1
	INC WIN+1
	LDX #10
	LDY #29	
	JSR HRC
	JMP GH2
GH1	JSR NBD
GH2	JSR REBR
	RTS

REBR	LDX #0
	LDY #133	
	JSR HRC
	LDA WIN
	LDX #145
	JSR NUMB
	LDX #10
	LDY #173	
	JSR HRC
	LDA WIN+1
	LDX #185
	JSR NUMB
	LDA NPLR
	BEQ WX
	LDX #20
	LDY #213	
	JSR HRC
	LDA WIN+2
	LDX #225
	JSR NUMB
WX	RTS

ZAVER	LDA NPLR
	BEQ TW11

	LDA WIN+1
	CMP WIN
	BMI HP0
	BEQ SC
	CMP WIN+2
	BEQ YET
	BMI HP3	
	LDX #10
	JMP HP9
SC	CMP WIN+2
	BMI HP3
	JMP YET
HP0	LDA WIN+2
	CMP WIN
	BMI HP1
	BEQ YET
HP3	LDX #20
	JMP HP9
HP1	LDX #0
HP9	LDA #DL2:L
	STA 560
	LDA #DL2:H
	STA 561
	LDA #1
	STA ZOK
	LDY #108
	JSR HRC
HP8	LDA 53279
	CMP #6
	BNE HP8
	RTS

TW11	LDA WIN
	CMP WIN+1
	BEQ YET
	LDA #1	
	STA ZOK
	LDA #DL2:L
	STA 560
	LDA #DL2:H
	STA 561	
	LDA WIN
	CMP WIN+1
	BMI WTW
	LDX #0
	JMP AF0
WTW	LDX #10
AF0	LDY #108
	JSR HRC
AO	LDA 53279
	CMP #6
	BNE AO
	RTS

YET	LDA #DL3:L
	STA 560
	LDA #DL3:H
	STA 561
AO0	LDA 53279
	CMP #6
	BNE AO0
	RTS

	DFB 0,0,0,0,0,0,0,0
	DFB 0,0,0,0,0,0,0,0
	DFB 0,0,0,0,0,0,0,0


DL2	DFB 112,112,112,128
	DFB 112,112,16
	DFB 128,32,78,LVRM:L,LVRM:H
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,128
	DFB 16,78,WVRM:L,WVRM:H
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,16
	DFB 128,112,112,32,128
	DFB 66,LINE8:L,LINE8:H,16
	DFB 128,112,112
	DFB 65,DL2:L,DL2:H

DL3	DFB 112,112,112,128
	DFB 112,112,112
	DFB 128,32,78,LVRM:L,LVRM:H
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,128
	DFB 16,128,112,112,16,128,66
	DFB LINE7:L,LINE7:H,16,128
	DFB 112,112,65,DL3:L,DL3:H