*CHESS.4
*LBL+TXT:STANDARD
*START:$5000
*NEED:CHSIN.BIN  - $B700
*     CHESS.BIN  - $A000

	ORG $B000
DL1	DFB 112,112
HERE1	DFB 0

	ORG $B400
DL2	DFB 112,112
HERE2	DFB 0



	ORG $5000

CHESS	EQU $A000
CH1	EQU $A300
CHI1	EQU $A600
CH2	EQU $A900
CHI2	EQU $AC00
MUL	EQU $AF00
MUH	EQU $AF80
SIN	EQU $B700
COS	EQU $B780
LI1	EQU $B800
LI2	EQU $B828
LI3	EQU $B850
LI4	EQU $B878


* ZERO *

ZH	EQU $80,$81
KR	EQU $82,$83
OD	EQU $84,$85
XP1	EQU $86
YP1	EQU $87
XP2	EQU $88
YP2	EQU $89
POY1	EQU $8A
POY2	EQU $8B
M1	EQU $8C,$8D
M2	EQU $8E,$8F
FLAG	EQU $90
CNT	EQU $91
CNT1	EQU $92
ML	EQU $93
MH	EQU $94
LPOC	EQU $95

	LDA #5
	STA 708
	LDA #9
	STA 709
	LDA #13
	STA 710

	JSR GEN
	JSR TABLE
	JMP GO

GEN	LDA #CH1:L
	STA $80
	LDA #CH1:H
	STA $81
	LDA #CHI1:L
	STA $82
	LDA #CHI1:H
	STA $83
	LDA #CH2:L
	STA $84
	LDA #CH2:H
	STA $85
	LDA #CHI2:L
	STA $86
	LDA #CHI2:H
	STA $87
	LDA #CHESS:L
	STA $88
	LDA #CHESS:H
	STA $89
	LDX #15	

LOOP	LDY #39
RK	LDA ($88),Y
	STA CHAR
	EOR #255
	STA ICHAR
	LDA #85
	AND CHAR
	STA ($80),Y
	LDA #85
	AND ICHAR
	STA ($82),Y
	LDA #170
	AND CHAR
	STA ($84),Y
	LDA #170
	AND ICHAR
	STA ($86),Y
	DEY
	BPL RK

	LDA $80
	CLC
	ADC #40
	STA $80
	BCC V1
	INC $81
V1	LDA $82
	CLC
	ADC #40
	STA $82
	BCC V2
	INC $83
V2	LDA $84
	CLC
	ADC #40
	STA $84
	BCC V3
	INC $85
V3	LDA $86
	CLC
	ADC #40
	STA $86
	BCC V4
	INC $87
V4	LDA $88
	CLC
	ADC #40
	STA $88
	BCC V5
	INC $89
V5	DEX
	BPL LOOP
	RTS

CHAR	NOP
ICHAR	NOP

TABLE	LDX #63	
HY	TXA
	STX CHAR
	JSR MUL40
	LDX CHAR
	LDA ML
	STA MUL,X
	LDA MH
	STA MUH,X
	DEX
	BPL HY
	RTS
MUL40	STA ML
	LDA #0
	STA MH
	ASL ML
	ASL ML
	ASL ML
	ROL MH
	LDA ML
	TAX
	LDA MH
	TAY
	ASL ML
	ROL MH
	ASL ML
	ROL MH
	TXA
	CLC
	ADC ML
	STA ML
	TYA
	ADC MH
	STA MH
	RTS

GO	LDA #12
	STA XP1
	LDA #48
	STA YP1

	LDA #0
	STA XP2
	LDA #126
	STA YP2


AGAIN	LDA #0
	STA FLAG
	JSR GET
	JSR LINES
	JSR MAKE
	JSR NEXT
	LDA 20
AA	CMP 20
	BEQ AA
	LDA #DL1:L
	STA 560
	LDA #DL1:H
	STA 561
	LDA #1
	STA FLAG
	JSR GET
	JSR LINES
	JSR MAKE
	JSR NEXT
	LDA 20
BB	CMP 20
	BEQ BB
	LDA #DL2:L
	STA 560
	LDA #DL2:H
	STA 561
	JMP AGAIN

NEXT	INC XP1
	INC XP2
	LDA XP1
	AND #127
	STA XP1
	LDA XP2
	AND #127
	STA XP2

	INC YP1
	INC YP2
	LDA YP1
	AND #127
	STA YP1
	LDA YP2
	AND #127
	STA YP2
	RTS

GET	LDX XP1
	LDA SIN,X
	LSR
	TAX
	LDA MUL,X
	STA M1
	LDA MUH,X
	CLC
	ADC #CH1:H
	STA M1+1
	LDX XP2
	LDA COS,X
	LSR
	TAX
	LDA MUL,X
	STA M2
	LDA MUH,X
	CLC
	ADC #CH2:H
	STA M2+1
	LDX YP1
	LDA COS,X
	STA POY1
	LDX YP2
	LDA SIN,X
	STA POY2
	RTS

LINES	LDA #39
	STA CNT
	LDA #3
	STA CNT1

FK	LDY CNT
	LDA (M1),Y
	TAX
	ORA (M2),Y
	STA LI1,Y
	TXA
	LDY CNT1
	ORA (M2),Y
	LDY CNT
	STA LI2,Y
	LDY CNT1
	LDA (M1),Y
	TAX
	ORA (M2),Y
	LDY CNT
	STA LI3,Y
	TXA
	ORA (M2),Y
	STA LI4,Y
	DEC CNT1
	BPL WW
	LDA #39
	STA CNT1
WW	DEC CNT
	BPL FK
	RTS

MAKE	LDX #200
	LDA FLAG
	BEQ FRST
	LDA #HERE2:L
	STA KR
	LDA #HERE2:H
	STA KR+1
	JMP HJ

FRST	LDA #HERE1:L
	STA KR
	STA ZH
	LDA #HERE1:H
	STA KR+1
	STA ZH+1

*B-BASE N-NEGOVANE

HJ	LDA POY1
	CMP #32
	BMI STE
	LDA POY1
	CMP #32
	BMI FBSB
	JMP FBSN
STE	LDA POY1
	CMP #32
	BMI FNSB1
	JMP FNSN

KONIEC1	JMP KONIEC
FNSB1	JMP FNSB

FBSB	LDY #0
	LDA #64+14
	STA (KR),Y
	INY
	LDA #LI1:L
	STA (KR),Y
	INY
	LDA #LI1:H
	STA (KR),Y
	JSR MBI
	DEX
	BEQ KONIEC1	

	INC POY2
	INC POY1

	LDA POY1
	CMP #32
	BEQ T2
	LDA POY2
	CMP #32
	BNE FBSB
	LDA #0
	STA POY2
	JMP FBSN
T2	LDA #0
	STA POY1
	LDA POY2
	CMP #32
	BNE FNSB
	LDA #0
	STA POY2
	JMP FNSN

FBSN	LDY #0
	LDA #64+14
	STA (KR),Y
	INY
	LDA #LI2:L
	STA (KR),Y
	INY
	LDA #LI2:H
	STA (KR),Y
	JSR MBI
	DEX
	BEQ KONIEC1

	INC POY2
	INC POY1

	LDA POY1
	CMP #32
	BEQ T21
	LDA POY2
	CMP #32
	BNE FBSN
	LDA #0
	STA POY2
	JMP FBSB
T21	LDA #0
	STA POY1
	LDA POY2
	CMP #32
	BNE FNSN
	LDA #0
	STA POY2
	JMP FNSB

FNSB	LDY #0
	LDA #64+14
	STA (KR),Y
	INY
	LDA #LI4:L
	STA (KR),Y
	INY
	LDA #LI4:H
	STA (KR),Y
	JSR MBI
	DEX
	BEQ KONIEC	
	INC POY2
	INC POY1
	LDA POY1
	CMP #32
	BEQ T22
	LDA POY2
	CMP #32
	BNE FNSB
	LDA #0
	STA POY2
	JMP FNSN
T22	LDA #0
	STA POY1
	LDA POY2
	CMP #32
	BNE FBSB2
	LDA #0
	STA POY2
	JMP FBSN
FBSB2	JMP FBSB

FNSN	LDY #0
	LDA #64+14
	STA (KR),Y
	INY
	LDA #LI3:L
	STA (KR),Y
	INY
	LDA #LI3:H
	STA (KR),Y
	JSR MBI
	DEX
	BEQ KONIEC	

	INC POY2
	INC POY1

	LDA POY1
	CMP #32
	BEQ T23
	LDA POY2
	CMP #32
	BNE FNSN
	LDA #0
	STA POY2
	JMP FNSB
T23	LDA #0
	STA POY1
	LDA POY2
	CMP #32
	BNE FBSN2
	LDA #0
	STA POY2
	JMP FBSB

FBSN2	JMP FBSN
KONIEC	LDY #0
	LDA #65
	STA (KR),Y
	INY
	LDA ZH
	STA (KR),Y
	INY
	LDA ZH+1
	STA (KR),Y
	RTS

MBI	LDA KR
	CLC
	ADC #3
	STA KR
	BCC FB
	INC KR+1
FB	RTS