*GLOBES.4
*LBL.TXT:$2000-$23FF.$2400-$3FFF
*START:$A000
*NEED:GLOBES.BIN - $B000

	ORG $A000

SPEED	EQU $1
BALL	EQU $0

VRAM1	EQU $4000
VRAM2	EQU $6000
VRAM3	EQU $8000
GLOBE	EQU $B000
EDGES	EQU $B100
X2SIN	EQU $B400
Y2SIN	EQU $B500
H4SIN	EQU $B600
TLO	EQU $B700
THI	EQU $B800

	LDA #0
	STA $DA
	LDA #$40
	STA $DB
LKJ	LDY #0
QZ	LDA #0
	STA ($DA),Y
	DEY
	BNE QZ
	INC $DB
	LDA $DB
	CMP #$A0
	BNE LKJ

	LDA #33
	STA 559
	LDA #13+16*0
	STA 708
	LDA #9+16*9
	STA 709
	LDA #5+16*9
	STA 710
	LDA #DL:L
	STA 560
	LDA #DL:H
	STA 561
	JSR MAKETAB
	LDA #0
	STA WHERE
	LDX #VBI:H
	LDY #VBI:L
	LDA #7
	JSR $E45C

IU	JMP IU


POM	NOP
FROM	NOP
YT	NOP
WHERE	NOP

PAINT	LDA WHERE
	BEQ FIRST
	CMP #1
	BEQ SCND
	LDA $DB
	CLC
	ADC #64
	STA $DB
	JMP FIRST
SCND	LDA $DB
	CLC
	ADC #32
	STA $DB
FIRST	LDA $DA
	STA TDA
	LDA $DB
	STA TDB
	LDY YT
	LDX FROM
	LDA TAB,X	
	TAX
	LDA #2
	STA CNTR

LOOP	LDA #17
	STA POC
ZA	LDA ($DA),Y
	AND EDGES,X
	ORA GLOBE,X
OK1	STA ($DA),Y
	INX
	LDA $DA
	CLC
	ADC #32
	STA $DA
	BCC FR
	INC $DB

FR	DEC POC
	BPL ZA

	INY
	LDA TDA
	STA $DA
	LDA TDB
	STA $DB

	DEC CNTR
	BPL LOOP
	RTS

POC	NOP
TDA	NOP
TDB	NOP
CNTR	NOP
QS	NOP

TAB	DFB 0,54,108,162

DL	DFB 0
	DFB 112
	DFB 64+14
HERE1	DFB 00,00
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14
	DFB 64+14
HERE2	DFB 0,0
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14,14
	DFB 14,14,14,14,14,14,14
	DFB 65,DL:L,DL:H

MAKETAB	LDA #VRAM1:L
	STA $DA
	LDA #VRAM1:H
	STA $DB
	LDX #0
QW	LDA $DA
	STA TLO,X
	LDA $DB
	STA THI,X
	LDA $DA
	CLC
	ADC #32
	STA $DA
	BCC D1
	INC $DB
D1	INX
	CPX #224
	BNE QW
	RTS

FLG	DFB 0
CNT	DFB 0
QQQQ	NOP

VON1	JMP $E462

VBI	INC CNT
	LDA CNT
	CMP #SPEED
	BNE VON1
	LDA #0
	STA CNT

	LDA WHERE
	BEQ NL
	CMP #1
	BEQ ON
	LDA #VRAM3:L
	STA HERE1
	STA HERE2
	LDA #VRAM3:H
	STA HERE1+1
	CLC
	ADC #16
	STA HERE2+1
	JMP VON

ON	LDA #VRAM2:L
	STA HERE1
	STA HERE2
	LDA #VRAM2:H
	STA HERE1+1
	CLC
	ADC #16
	STA HERE2+1
	JMP VON
NL	LDA #VRAM1:L

	STA HERE1
	STA HERE2
	LDA #VRAM1:H
	STA HERE1+1
	CLC
	ADC #16
	STA HERE2+1

VON	LDA #BALL
	STA QQQQ

LO2	LDY QQQQ
	LDX PX,Y
	LDA X2SIN,X
	STA POM
	LDX PAX,Y
	LDA H4SIN,X
	CLC
	ADC POM
	PHA
	AND #3
	STA FROM
	PLA
	LSR
	LSR
	STA YT
	LDX PY,Y
	LDA Y2SIN,X
	STA POM
	LDX PAY,Y
	LDA H4SIN,X
	ASL
	CLC
	ADC POM
	TAY
	LDA TLO,Y
	STA $DA
	LDA THI,Y
	STA $DB
	JSR PAINT
	DEC QQQQ
	BPL LO2


	INC WHERE
	LDA WHERE
	CMP #3
	BNE AZ
	LDA #0
	STA WHERE

AZ	LDX #BALL
Q7	INC PX,X
	INC PY,X
	INC PAX,X
	INC PAY,X
	LDA PAX,X
	CMP #63
	BNE ZK1
	LDA #0
	STA PAX,X
ZK1	LDA PAY,X
	CMP #63
	BNE ZK2
	LDA #0
	STA PAY,X
ZK2	DEX
	BPL Q7

QJ	JMP $E462

PX	DFB $70
	DFB $0
	DFB $80
	DFB $80

PY	DFB $32
	DFB $80
	DFB $80
	DFB $0

PAX	DFB $12
	DFB $20
	DFB $0
	DFB $0

PAY	DFB $21
	DFB $0
	DFB $0
	DFB $0