*GR8ZOOM.4
*LBL+TXT:STANDARD
*START:$5000
*NEED:/  (SMALL FONT 6-LINES)

	ORG $5500

DL	DFB 0,0,0,0,0,0,0
HERE	DFB 0

	ORG $5000

VRAM	EQU $8000
VRAM1	EQU $8100
XPOS	EQU $8200
CUT	EQU $8300
MOVE	EQU $8400
XTAB	EQU $8500
TTAB	EQU $8600

* ZERO *

OD	EQU $80,$81
PL	EQU $82,$83
KR	EQU $84,$85
ML	EQU $86
MH	EQU $87
CNT	EQU $86
POC	EQU $87
SMER	EQU $88
FAZA	EQU $89
BYTE	EQU $8A
POSUN	EQU $8B
VB	EQU $8C,$8D

	JMP NET

DATA	DFB 112,112,112,112
	DFB 96,96,96
	DFB 64+15
	DFW VRAM+32*0
	DFB 64+15
	DFW VRAM+32*1
	DFB 64+15
	DFW VRAM+32*2
	DFB 64+15
	DFW VRAM+32*3
	DFB 64+15
	DFW VRAM+32*4
	DFB 64+15
	DFW VRAM+32*5
	DFB 64+15
	DFW VRAM+32*6
	DFB 64+15
	DFW VRAM+32*7
	DFB 65,DL:L,DL:H

SETVBI	LDA #7
	LDX #VBI:H
	LDY #VBI:L
	JSR $E45C
	RTS

INIT	LDX #0
	LDY #128
LG	TXA
	LSR
	LSR
	LSR
	STA XPOS,X
	TYA
	STA CUT,X
	LSR
	TAY
	BNE RD
	LDY #128
RD	TXA
	STA TTAB,X
	AND #7
	STA MOVE,X
	INX
	BNE LG
	RTS

INIT1	LDX #0
DPX	TXA
	STA XTAB,X
	INX
	BNE DPX
	RTS

COPY	LDA #31
	TAY
	STA CNT1


BLO	LDA #VRAM1:L
	STA $DA
	LDA #VRAM1:H
	STA $DB


	LDA #0
	STA HI1
	LDX CNT1
	LDA TEXT,X
	STA LO1
	ASL LO1
	ROL HI1
	ASL LO1
	ROL HI1
	ASL LO1
	ROL HI1
	LDA LO1
	STA HR+1
	LDA HI1
	CLC
	ADC #$E0
	STA HR+2
	LDX #0
HR	LDA $2000,X
	STA ($DA),Y
	LDA $DA
	CLC
	ADC #32
	STA $DA
	BCC AS1
	INC $DB
AS1	INX
	CPX #8
	BNE HR
	DEY
	DEC CNT1
	BPL BLO

	LDX #0
DDP	LDA VRAM1,X
	STA VRAM,X
	INX
	BNE DDP
	RTS

LO1	NOP
HI1	NOP
CNT1	NOP


TEXT	ASC %                %
	ASC %                %

TEXT1	ASC %             PLE%
	ASC %ASE             %
	ASC %            TURN%
	ASC % THE            %
	ASC %              DI%
	ASC %SK              %


GO	LDA #0
	STA FAZA
	STA TTT

AGAIN	JSR PAINT

	JSR CTRL
	JSR COUNT
	LDA TTT
	CMP #30
	BNE DXX
	LDA #0
	STA CAN
	RTS
DXX	JMP AGAIN

CTRL	INC FAZA
	LDA FAZA
	CMP #32
	BNE DC
	LDA #0
	STA FAZA
	INC TTT
DC	RTS

TTT	NOP

COUNT	LDX FAZA
	LDA MATRIX,X
	PHA
	EOR #31
	TAX
YH1	INC XTAB+128,X
	INX
	BNE YH1
	PLA
	TAX
YH	DEC XTAB+96,X
	DEX
	BPL YH
	RTS

PAINT	JSR LEFT
	JSR RIGHT
	RTS

RIGHT	JSR ZAC1
	JSR REP1
	JSR R0
	JSR REP1
	JSR R0
	JSR REP1
	JSR R0
	JSR REP1
	JSR R0
	JSR REP1
	JSR R0
	JSR REP1
	JSR R0
	RTS

LEFT	JSR ZAC
	JSR REP
	JSR L0
	JSR REP
	JSR L0
	JSR REP
	JSR L0
	JSR REP
	JSR L0
	JSR REP
	JSR L0
	JSR REP
	JSR L0
	RTS

ZAC	LDA #0
	STA M1+1
	STA M2+1
	STA M3+1
	STA M4+1
	STA M5+1
	RTS

ZAC1	LDA #0
	STA R1+1
	STA R2+1
	STA R3+1
	STA R4+1
	STA R5+1
	RTS


REP1	LDA R1+1
	CLC
	ADC #32
	STA R1+1
	STA R2+1
	STA R3+1
	STA R4+1
	STA R5+1
	RTS		

REP	LDA M1+1
	CLC
	ADC #32
	STA M1+1
	STA M2+1
	STA M3+1
	STA M4+1
	STA M5+1
	RTS		

L0	LDX #127

WS	LDY XTAB,X
	BMI END
	LDA XPOS,Y
	STA BYTE
	LDA MOVE,Y
	STA POSUN
	TXA
	TAY
	LDA CUT,Y
	PHA
	LDA XPOS,Y
	TAY
	PLA
M5	AND VRAM1+32*0,Y
	BNE PIXEL
	LDY POSUN
	LDA CUT,Y
	EOR #255
	LDY BYTE
M4	AND VRAM+32*0,Y
M3	STA VRAM+32*0,Y
	JMP NEXT
PIXEL	LDY POSUN
	LDA CUT,Y
	LDY BYTE
M1	ORA VRAM+32*0,Y
M2	STA VRAM+32*0,Y
NEXT	DEX
	CPX #95
	BNE WS
END	RTS

R0	LDX #128
WS1	LDY XTAB,X
	BPL END1
	LDA XPOS,Y
	STA BYTE
	LDA MOVE,Y
	STA POSUN
	TXA
	TAY
	LDA CUT,Y
	PHA
	LDA XPOS,Y
	TAY
	PLA
R5	AND VRAM1+32*0,Y
	BNE PIX1
	LDY POSUN
	LDA CUT,Y
	EOR #255
	LDY BYTE
R4	AND VRAM+32*0,Y
R3	STA VRAM+32*0,Y
	JMP NEXT1
PIX1	LDY POSUN
	LDA CUT,Y
	LDY BYTE
R1	ORA VRAM+32*0,Y
R2	STA VRAM+32*0,Y
NEXT1	INX
	CPX #161
	BNE WS1
END1	RTS

VBI	LDA CAN
	BEQ ZL
	JSR DLIST
ZL	JMP $E462

DLIST	JSR CREATE
	JSR RATAJ
	RTS

DTAB	DFB 0,0,0,0,0,0,0,0

SMTX	DFB 0,6,4,1,0,2,5,3,7,0
COMP	DFB 0,2,4,6,8,10,12,14,16
	DFB 18,20,22,24,26,28,30

RATAJ	LDA FAZA
	LDX #15
HK	CMP COMP,X
	BEQ HL
	DEX
	DEX
	BPL HK
	RTS
HL	TXA
	LSR
	TAX
	LDA SMTX,X
	TAX
	INC DTAB,X
	RTS

CREATE	LDA #HERE:L
	STA VB
	LDA #HERE:H
	STA VB+1
	LDX #1
DX	LDY DTAB,X
HM	STY POM
	LDY #0
	LDA #64+15
	STA (VB),Y
	INY
	LDA LTAB,X
	STA (VB),Y
	INY
	LDA HTAB,X
	STA (VB),Y	
	LDA VB
	CLC
	ADC #3
	STA VB
	BNE DN
	INC VB+1
DN	LDY POM
	DEY
	BPL HM
	INX
	CPX #8
	BNE DX
	LDA #65
	LDY #0
	STA (VB),Y
	INY
	LDA #DL:L
	STA (VB),Y
	INY
	LDA #DL:H
	STA (VB),Y
	RTS

LTAB	DFB 0,32,64,96,128,160
	DFB 192,224

HTAB	DFB 128,128,128,128
	DFB 128,128,128,128

POM	NOP

MATRIX	DFB 16,0
	DFB 8,24
	DFB 4,20
	DFB 12,28
	DFB 2,18
	DFB 10,26
	DFB 6,22
	DFB 14,30
	DFB 17,1
	DFB 9,25
	DFB 5,21
	DFB 13,29
	DFB 3,19
	DFB 11,27
	DFB 7,23
	DFB 15,31

ZMIZ	LDX #12
UH	STX 709
	JSR WAIT
	DEX
	DEX
	BPL UH
	RTS

ZJAV	LDX #0
HU	STX 709
	JSR WAIT
	INX
	INX
	CPX #14
	BNE HU
	RTS

WAIT	LDA #0
	STA 20
RC	LDA 20
	CMP #4
	BNE RC
	RTS

NEWINIT	LDX #7
GG	LDA #0
	STA DTAB,X
	DEX 
	BPL GG
	JSR INIT1
	JSR INITD
	RTS

INITD	LDX #40
YV	LDA DATA,X
	STA DL,X
	DEX
	BPL YV
	RTS

CAN	NOP

MOV	LDY #0
TC	LDA TEXT1,X
	STA TEXT,Y
	INX
	INY
	CPY #32
	BNE TC
	RTS

NET	LDA #33
	STA 559
	LDA #0
	STA 710
	STA 709
	STA CAN
	JSR NEWINIT
	LDA #DL:L
	STA 560
	LDA #DL:H
	STA 561
	LDX #0
	JSR MOV
	JSR COPY
	JSR INIT
	JSR SETVBI
	JSR ZJAV
	LDA #1
	STA CAN
	JSR GO
	JSR ZMIZ
	LDX #32
	JSR MOV
	JSR COPY

	JSR NEWINIT
	JSR ZJAV
	LDA #1
	STA CAN
	JSR GO
	JSR ZMIZ

	LDX #64
	JSR MOV
	JSR COPY

	JSR NEWINIT
	JSR ZJAV
	LDA #1
	STA CAN
	JSR GO
	JSR ZMIZ
MN	JMP MN