*LIGHTGR9.4
*LBL+TXT:STANDARD
*START :$5000
*(GR9.PIC)   - $6100
*LIGHT.BIN   - $B200

	ORG $5000

VEL	EQU $01

*	OUT N

VRAM0	EQU $6100
VRAM1	EQU $8100

LO	EQU $A000
HI	EQU $A100
XPOS	EQU $A200
LNIB	EQU $A300
HNIB	EQU $A400
BNIB	EQU $A500
ST0	EQU $A600
ST1	EQU $A800
ST2	EQU $AA00
ST3	EQU $AC00
ST4	EQU $AE00
ST5	EQU $B000
SIN	EQU $B200
COS	EQU $B300

UX	EQU $E0
UY	EQU $E1
C0	EQU $E2	;-$E5
VC	EQU $E6
NMB	EQU $E7

KR	EQU $82,$83
PL	EQU $84,$85
ZH	EQU $86,$87
XS	EQU $88
YS	EQU $89
POC	EQU $8A
POC1	EQU $8B
X1	EQU $8C
Y1	EQU $8D	;-$91
SX1	EQU $92
SY1	EQU $93	;-$97	
MX	EQU $98
MY	EQU $99  ;-$9D

UX1	EQU $A0
UY1	EQU $A1
UX2	EQU $A2
UY2	EQU $A3


	LDA #DL:L
	STA 560
	LDA #DL:H
	STA 561

	JSR INIT

	LDA #34
	STA 559
	LDA #64
	STA 623


	JMP PPPP



KD	LDA #VRAM0:L
	STA $DA
	LDA #VRAM0:H
	STA $DB

RR	LDY #0
H	LDA 53770
	AND #7
	TAX
	LDA TAB,X
	STA ($DA),Y
	INY
	BNE H
	INC $DB
	LDA $DB
	CMP #$7F
	BNE RR

	LDA #1
	STA UX
	STA UY


KP	LDA #0
	STA NMB
	LDX UX
	DEX
	LDY UY
	JSR LOCATE

	LDA #1
	STA NMB
	LDX UX
	INX
	LDY UY
	JSR LOCATE

	LDA #2
	STA NMB
	LDX UX
	LDY UY
	DEY
	JSR LOCATE

	LDA #3
	STA NMB
	LDX UX
	LDY UY
	INY
	JSR LOCATE
	JSR PRIE
	JSR PLOT

	INC UX
	LDA UX
	CMP #79
	BNE KP
	LDA #1
	STA UX
	INC UY
	LDA UY
	CMP #191
	BNE KP

PPPP	JSR COPY

LK	LDA 53279
	CMP #6
	BEQ GO1
	JMP LK

GO1	JMP GO

COPY	LDA #0
	STA $DA
	STA $DC
	LDA #VRAM0:H
	STA $DB
	LDA #VRAM1:H
	STA $DD

DP1	LDY #0
DP	LDA ($DA),Y
	STA ($DC),Y
	INY
	BNE DP	
	INC $DB
	INC $DD
	LDA $DB
	CMP #$7F
	BNE DP1
	RTS

DL	DFB 112,112,112
	DFB 64+15,0
SCR0	DFB VRAM0:H
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15
	DFB 64+15,0
SCR1	DFB $70
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15,15
	DFB 15,15,15,15,15,15,15
	DFB 65,DL:L,DL:H

INIT	LDA #VRAM0:L
	STA $DA
	LDA #VRAM0:H
	STA $DB
	LDY #0

OO	LDA $DA
	STA LO,Y
	LDA $DB
	STA HI,Y
	LDA $DA
	CLC
	ADC #40
	STA $DA
	BCC T
	INC $DB
T	INY
	BNE OO

	LDX #0
	LDY #0
RD1	TYA
	LSR
	STA XPOS,X
	INY
	CPY #80
	BNE RD
	LDY #0
RD	INX
	BNE RD1

	LDX #0
LOOP	TXA
	AND #15
	STA HLP
	TAY
	TXA
	AND #240
	ORA PTAB,Y
	STA LNIB,X
	TXA
	AND #240
	LSR
	LSR
	LSR
	LSR
	TAY
	LDA PTAB,Y
	ASL
	ASL
	ASL
	ASL
	ORA HLP
	STA HNIB,X
	LDA HNIB,X
	AND #240
	STA HLP
	LDA LNIB,X
	AND #15
	ORA HLP
	STA BNIB,X
	INX
	BNE LOOP
	RTS

HLP	NOP

PTAB	DFB 3,4,5,6,7,8,9,10,11,12
	DFB 13,14,15,15,15,15


PRIE	LDX #3
	LDA #0
UH	CLC
	ADC C0,X
	DEX
	BPL UH
	LSR
	LSR
	STA VC
	RTS

LOCATE	LDA LO,Y
	STA $DA
	LDA HI,Y
	STA $DB
	TXA
	LSR
	TAY
	TXA
	AND #1
	BEQ BIG
	LDA ($DA),Y
	AND #15
	LDX NMB
	STA C0,X
	RTS

BIG	LDA ($DA),Y
	AND #240
	LSR
	LSR
	LSR
	LSR
	LDX NMB
	STA C0,X
	RTS

PLOT	LDY UY
	LDA LO,Y
	STA $DA
	LDA HI,Y
	STA $DB
	LDA UX
	LSR
	TAY
	LDA UX
	AND #1
	BEQ HIGH
	LDA ($DA),Y
	AND #240
	ORA VC
	STA ($DA),Y
	RTS
HIGH	LDA ($DA),Y
	AND #15
	ASL VC
	ASL VC
	ASL VC
	ASL VC
	ORA VC
	STA ($DA),Y
	RTS

TAB	DFB $00,$11,$22,$33,$44
	DFB $55,$66,$77,$88,$99
	DFB $AA,$BB,$CC,$DD,$EE
	DFB $FF


F0	DFB 0,0,0,15,15,255,255,255
	DFB 15,15,0,0,0

	DFB 0,15,255,255,255,255,255
	DFB 255,255,255,255,15,0

	DFB 15,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 15

	DFB 255,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 255

	DFB 0,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 0

	DFB 0,0,240,255,255,255,255
	DFB 255,255,255,240,0,0

	DFB 0,0,0,0,0,240,240,240
	DFB 0,0,0,0,0

F1	DFB 0,0,0,0,0,15,15,15,0,0,0
	DFB 0,0

	DFB 0,0,15,255,255,255,255
	DFB 255,255,255,15,0,0

	DFB 0,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 0

	DFB 255,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 255

	DFB 240,255,255,255,255,255
	DFB 255,255,255,255,255,255
	DFB 240

	DFB 0,240,255,255,255,255
	DFB 255,255,255,255,255,240
	DFB 0

	DFB 0,0,0,240,240,255,255
	DFB 255,240,240,0,0,0

FLG	NOP

GO	JSR SPT
	LDX #17
GD	LDA #0
	STA X1,X
	DEX
	BPL GD

	LDA #0
	STA FLG
	JSR COPMX
	JSR PAINT
	LDA #1
	STA FLG
	JSR COPMX
	JSR PAINT
	LDA #3
	STA FLG
	JSR COPMX
	JSR PAINT
	LDA #4
	STA FLG
	JSR COPMX
	JSR PAINT

BLOOP	LDA 20
AP	CMP 20
	BNE AP
	LDA #VRAM0:H
	STA SCR0
	CLC
	ADC #15
	STA SCR1
	JSR CTRL
	LDA #4
	STA FLG
	JSR GET
	JSR RESTORE
	LDA #3
	STA FLG
	JSR GET
	JSR RESTORE
	JSR COPMX
	JSR PAINT
	LDA #4
	STA FLG	
	JSR COPMX		
	JSR PAINT
	LDA 20
WL	CMP 20
	BEQ WL
	LDA #VRAM1:H
	STA SCR0
	CLC
	ADC #15
	STA SCR1
	JSR CTRL
	LDA #1
	STA FLG
	JSR GET
	JSR RESTORE
	LDA #0
	STA FLG
	JSR GET
	JSR RESTORE
	JSR COPMX
	JSR PAINT
	LDA #1
	STA FLG	
	JSR COPMX		
	JSR PAINT

	JMP BLOOP

PY	NOP

COPMX	LDA FLG
	ASL
	TAX
	LDY WTAB,X
	LDA MY,Y
	STA Y1,X
	STA PY
	LDA MX,Y	
	STA X1,X
	TAX
	LDY PY
	RTS

WTAB	DFB 0,0,2,2,4,4,0,0,2,2,4,4

GET	LDA FLG
	ASL
	TAX
	LDY Y1,X
	LDA X1,X
	TAX
	RTS

CTRL	JSR BIG3
	JSR DLSI
	RTS

BIG3	LDX UX1
	LDA SIN,X
	LSR
	CLC
	ADC #15
	STA MX
	LDX UX2
	LDA SIN,X
	LSR
	CLC
	ADC #12
	STA MX+2
	LDX UY1
	LDA COS,X
	SEC
	SBC #15
	STA MY

	LDX UY2
	LDA COS,X
	SEC
	SBC #15
	STA MY+2

	RTS



DLSI	NOP

	INC UX1
	INC UX2
	INC UY1
	INC UY2
	INC UY1
	INC UY2


	INC UX1
	INC UX2
	INC UY1
	INC UY2
	INC UY1
	INC UY2

	LDA UY1
	CMP #254
	BNE SA
	LDA #0
	STA UY1

SA	LDA UY2
	CMP #254
	BNE TJ
	LDA #0
	STA UY2
TJ	RTS




PAINT	TXA
	PHA
	LDA FLG
	ASL
	TAX
	LDA STOTAB,X
	STA SEM+1
	LDA STOTAB+1,X
	STA SEM+2
	PLA
	TAX
	LDA FLG
	CMP #3
	BPL NGJ1

	LDA LO,Y
	CLC
	ADC XPOS,X
	STA KR
	STA ZH
	LDA HI,Y
	ADC #0
	STA KR+1
	STA ZH+1
	JMP HF1

NGJ1	LDA LO,Y
	CLC
	ADC XPOS,X
	STA KR
	STA ZH
	LDA HI,Y
	ADC #32
	STA KR+1
	STA ZH+1

HF1	TXA
	AND #1
	BNE FZ1
	LDA #F0:L
	STA HERE+1
	LDA #F0:H
	STA HERE+2
	JMP CDF

FZ1	LDA #F1:L
	STA HERE+1
	LDA #F1:H
	STA HERE+2

CDF	LDY #0
	LDX #0

BB	LDA ZH
	STA KR
	LDA ZH+1
	STA KR+1

	LDA #0
	STA POC

CC	LDA #VEL
	STA POC1

DD	LDA (KR),Y
	PHA
SEM	STA $9000
HERE	LDA F0,X
	STX PL
	BEQ NXT1
	CMP #15
	BEQ SP
	CMP #240
	BEQ VR
	PLA
	TAX
	LDA BNIB,X
	JMP NXT
SP	PLA
	TAX
	LDA LNIB,X
	JMP NXT
VR	PLA
	TAX
	LDA HNIB,X
	JMP NXT
NXT1	PLA
	JMP JD
NXT	STA (KR),Y
JD	LDA KR
	CLC
	ADC #40
	STA KR
	BCC NF
	INC KR+1

NF	LDX PL
	INC SEM+1
	BNE DJ
	INC SEM+2
DJ	DEC POC1
	BPL DD
	INX
	INC POC
	LDA POC
	CMP #13
	BNE CC

	INY
	CPY #7
	BNE BB
	RTS



RESTORE	TXA
	PHA
	LDA FLG
	ASL
	TAX
	LDA STOTAB,X
	STA ASEM+1
	LDA STOTAB+1,X
	STA ASEM+2
	PLA
	TAX
	LDA FLG
	CMP #3
	BPL NGJ

	LDA LO,Y
	CLC
	ADC XPOS,X
	STA KR
	STA ZH
	LDA HI,Y
	ADC #0
	STA KR+1
	STA ZH+1
	JMP HF

NGJ	LDA LO,Y
	CLC
	ADC XPOS,X
	STA KR
	STA ZH
	LDA HI,Y
	ADC #32
	STA KR+1
	STA ZH+1

HF	LDY #0
	LDX #0

ABB	LDA ZH
	STA KR
	LDA ZH+1
	STA KR+1

	LDA #0
	STA POC

ACC	LDA #VEL
	STA POC1

ADD	NOP
ASEM	LDA $9000
	STA (KR),Y
	LDA KR
	CLC
	ADC #40
	STA KR
	BCC ANF
	INC KR+1
ANF	INC ASEM+1
	BNE DU
	INC ASEM+2
DU	DEC POC1
	BPL ADD
	INX
	INC POC
	LDA POC
	CMP #13
	BNE ACC
	INY
	CPY #7
	BNE ABB
	RTS

STOTAB	DFW ST0,ST1,ST2,ST3,ST4,ST5


SPT	LDA #86
	STA UX1
	LDA #11
	STA UY1
	LDA #34
	LDA UX2
	LDA #120
	STA UY2
	RTS