* KEFREN BARS VERSION 7
* PEDRO/GMG
* 16/04/97
*
	ORG $5000
	MKDIV4
	MKDL
	MKKEF
	INIT
	INSTALL
	MKXKEF
	PLAYINI

ZAC	MAZ
	MAIN
ZAC2	SYN
	LDA #85
	STA SPEC

	LDA $D01F
	CMP BUFER
	BEQ CONT
	STA BUFER
	CMP #5
	BEQ CHANGE
CONT	JMP ZAC

BUFER	DFB 0

CHANGE	LDX POINTER
	LDA XADCL,X
	STA XADC
	LDA XADCH,X
	STA XADC+1
	INC POINTER
	LDA POINTER
	CMP COMBI
	BNE QUIT
	LDA #0
	STA POINTER
QUIT	MAZ
	INSTALL
	JMP ZAC2

MAIN	LDX #84

MAI1	STX ZALOHA
	LDY TAB1,X
Q_1	LDA SINTAB,Y
	CLC
	LDY TAB2,X
Q_2	ADC SINTAB,Y
	TAX

DOIT	LDY DIV4,X

	LDA CVICNE,Y
	AND XANDLO,X
	ORA XKEFLO,X
	STA CVICNE,Y
	STA 0
	LDA CVICNE+1,Y
	AND XANDHI,X
	ORA XKEFHI,X
	STA CVICNE+1,Y

	LDX ZALOHA
	STA DATA2,X
	LDA 0
	STA DATA1,X
	TYA
	STA DATA3,X

	DEX POCIAR
	BPL MAI1	

	LDA Q_1+1
	CLC
	ADC SPD1
	STA Q_1+1

	LDA Q_2+1
	CLC
	ADC SPD2
	STA Q_2+1
	RTS


MKKEF	LDX #0

	LDA #%01101001
	STA HELP+1
	LDA #0
	STA HELP

MKK1	LDA HELP+1
	STA KEFTAB,X
	LDA HELP
	STA KEFTAB2,X

	LSR HELP+1
	ROR HELP
	LSR HELP+1
	ROR HELP

	INX
	CPX #4
	BNE MKK1

	LDA #0
	STA HELP
	LDA #255
	STA HELP+1

	LDX #0
MK4	LDA HELP
	STA LOAND,X
	LDA HELP+1
	STA HIAND,X

	LSR HELP+1
	ROR HELP
	LSR HELP+1
	ROR HELP

	INX
	CPX #4
	BNE MK4
	RTS

INIT	LDA #DL:L
	STA 560
	LDA #DL:H
	STA 561
	LDA #5
	STA 708	
	LDA #9
	STA 709
	LDA #DLI:L
	STA $200
	LDA #DLI:H
	STA $201
	LDA #192
	STA $D40E
	LDA #0
	STA READY

	LDX #0

UP	LDA $7300,X
	STA $7400,X

	INX
	BNE UP
	RTS


MKDL	LDA #112
	STA DL
	STA DL+1
	STA DL+2

	LDA #DL:L
	CLC
	ADC #3
	STA SCREEN
	LDA #DL:H
	ADC #0
	STA SCREEN+1

	LDX #100
MK2	LDY #0
MK1	LDA DLDATA,Y
	STA (SCREEN),Y
	INY
	CPY #12
	BNE MK1

	LDA SCREEN
	CLC
	ADC #6
	STA SCREEN
	LDA SCREEN+1
	ADC #0
	STA SCREEN+1

	DEX
	BNE MK2

	LDY #0
	LDA #$41
	STA (SCREEN),Y
	INY
	LDA #DL:L
	STA (SCREEN),Y
	INY
	LDA #DL:H
	STA (SCREEN),Y
	RTS

MAZ	LDX #0
	LDA #0
MA	STA VRAM,X
	STA CVICNE,X
	INX
	CPX #40
	BNE MA
	RTS


DLDATA	DFB 78,$40,$71
	DFB 78+128,$40,$71
DL	EQU $8000
CVICNE	EQU $7101
VRAM	EQU $7140
SCREEN	EQU $80,$81
KEFTAB	ORG *+10
KEFTAB2	ORG *+10
HELP	DFW 0
AKT	EQU $80,$81
STORE	DFW 0
SINTAB	EQU $7300
POCIAR	DFB $85
READY	DFB 0
LOAND	ORG *+8
HIAND	ORG *+8

SYN	LDA $D40B
	CMP #115
	BNE SYN
	RTS

DLI	STA $82
	STX 1

	LDX SPEC
	BEQ KONIEC

	LDY DATA3,X

	LDA DATA1,X
	STA VRAM,Y
	INY
	LDA DATA2,X
	STA VRAM,Y
	DEC SPEC

KONIEC	LDX 1
	LDA $82
	RTI

DATA1	ORG *+100
DATA2	ORG *+100
DATA3	ORG *+100
POINTER	DFB 0
COMBI	DFB 5
SPEC	EQU $84

TAB1	ORG *+256
TAB2	ORG *+256

INSTALL	LDA XADC
	STA CIS+1
	LDA XADC+1
	STA CIS2+1
	LDX #0
	STX AKT
	STX AKT+1

INS1	LDA AKT
QW_1	STA TAB1,X

	LDA AKT+1
QW_2	STA TAB2,X

	LDA AKT
	CLC
CIS	ADC #$FF
	STA AKT
	LDA AKT+1
	CLC
CIS2	ADC #$FF
	STA AKT+1

	INX
	BNE INS1
	RTS

ZALOHA	EQU $83 

MKXKEF	LDY #0

KE2	LDX #0

KE	LDA KEFTAB,X
	STA XKEFLO,Y
	LDA KEFTAB2,X
	STA XKEFHI,Y
	LDA LOAND,X
	STA XANDLO,Y
	LDA HIAND,X
	STA XANDHI,Y
	INY
	INX
	CPX #4
	BNE KE	

	CPY #0
	BNE KE2
	RTS


XKEFLO	ORG *+256
XKEFHI	ORG *+256
XANDLO	ORG *+256
XANDHI	ORG *+256

MKDIV4	LDX #0
DYV	TXA
	LSR
	LSR
	STA DIV4,X
	INX
	BNE DYV
	RTS

DIV4	ORG *+256


SPD1	DFB 2
SPD2	DFB 2
XADC	DFB 1,0

XADCL	DFB 5,5,4,123,2
XADCH	DFB 1,250,127,5,1


PLAYINI	LDA #MUS:L
	LDX #MUS:H
	INI
	LDA #6
	LDY #VBI:L
	LDX #VBI:H
	JMP $E45C

VBI	PLAY
	JMP $E462

MUS	EQU $A000
PLAY	EQU $6000
INI	EQU $6391