hlp	equ $80

ant1	equ $d800
ant2	equ ant1+$400

gr9     equ $2010
gra     equ gr9+$2000
grb     equ gra+$2000

*---

 mwa #nmi $fffa
 mwa #ant2 $230
 lda #$80
 sta tip_+1

 jsr create

 lda #$40       ;normalnie jest wartosc $40
 sta $d40e	;ok moze dzialac przerwanie DLI
	
 lda $d209
 sta old_+1

klik    lda $d40b
        cmp #4
        bne klik

	ldy #119
tip_	lda #$40
	ldx #$c0

	sta $d40a
	sta $d01b

	sta $d40a
	stx $d01b

	eor #$c0
	sta tip_+1

	dey
	bne tip_

	lda $231
	eor >ant1^ant2
	sta $231

 lda #0
 sta $d012
 lda #2
 sta $d013
 lda #4
 sta $d014
 lda #6
 sta $d015
 lda #8
 sta $d016
 lda #$a
 sta $d017
 lda #$c
 sta $d018
 lda #$e
 sta $d019
 lda #0
 sta $d01a

 lda $d20f
 and #4
 bne klik
 lda $d209
old_ cmp #$ff
 bne quit

 jmp klik
quit rts        ;wyjscie

*---
wai lda 20
 cmp 20
 beq *-2
 rts
*---

nmi pha
 sta $d40f
 
 inc $14
 mwa $230 $d402

 pla
 rti

;---
	
create	mwa #gr9 g9
	mwa #gra+40 ga
	mwa #grb gb
	mwa #ant1 hlp

	lda #60
	sta ile
cr	jsr get_b
	jsr get_9
	jsr get_b
	jsr get_a
	dec ile
	bne cr

	ldx >ant2
	jsr ant_end

;---
	mwa #gr9+40 g9
	mwa #gra ga
	mwa #grb gb
	mwa #ant2 hlp
	
	lda #60
	sta ile
cr_	jsr get_b
	jsr get_a
	jsr get_b
	jsr get_9
	dec ile
	bne cr_

	ldx >ant1

ant_end	lda hlp
        sec
        sbc #3
        sta hlp
        bcs *+4
        dec hlp+1

        ldy #0
	lda #$41
	sta (hlp),y
	tya
	iny
	sta (hlp),y
	iny
	txa
	sta (hlp),y
	rts

;---
	
get_9	ldx g9
	lda g9+1
	jsr _crea

	clc
	lda g9
	adc #80
	sta g9
	bcc g900
	inc g9+1
g900	rts
	
get_b	ldx gb
	lda gb+1
	jsr _crea

	clc
	lda gb
	adc #40
	sta gb
	bcc gb00
	inc gb+1
gb00	rts
	
get_a	ldx ga
	lda ga+1
	jsr _crea

	clc
	lda ga
	adc #80
	sta ga
	bcc ga00
	inc ga+1
ga00	rts

_crea	ldy #2
	sta (hlp),y
	dey
	txa
	sta (hlp),y
	dey
	lda #$4f
	sta (hlp),y
	
	lda hlp
	clc
	adc #3
	sta hlp
	bcc *+4
	inc hlp+1
	rts

;---
g9	:2 brk
ga	:2 brk
gb	:2 brk
ile	brk
;---